/* set line size and page size for easy viewing */
options linesize=80  pagesize=64;

/* data paragraphs are used to get, create and manipulate data */
data a;
   /* input file is "diet.dat"; "." or end of line = missing value */
   infile 'diet.dat' missover firstobs=2;
   /* blank-delimited fields (tabs not allowed) */
   input cow diet block covar dmi weeks;

/* proc paragraphs are used for analysis and plotting */
proc glm;			/* analysis of variance */
   class block diet;		/* diet is factor with discrete levels */
   weight weeks;			/* weight by number of measurements */
   model dmi = diet;		/* model statement */
   means diet;			/* means and standard deviations */
				/* multiple comparisons */
   means diet / lsd lines;	/* using harmonic mean of sample size */
   lsmeans diet / stderr pdiff;	/* using pairwise t-tests (LSD) */
   output out=plot p=pdmi r=rdmi; /* output for later plotting */

proc plot;
   plot  dmi * pdmi = diet;
   plot rdmi * pdmi = diet;
   plot rdmi * covar = diet;

proc glm;
   class block diet;
   weight weeks;			/* weight by number of measurements */
   model dmi = covar block diet; 
   lsmeans diet / stderr pdiff;
   estimate "UIP Ln Effect"     diet  -6 -1 -1  1  1  6  / divisor = 8 ;
   estimate "UIP Qr Effect"     diet   2 -1 -1 -1 -1  2  / divisor = 4 ;
   estimate "SBMc-ABP:124-356 " diet   1  1 -1  1 -1 -1  / divisor = 3 ;   
   estimate "SBM-ABPc:12-3456 " diet   2  2 -1 -1 -1 -1  / divisor = 4 ;   
   estimate "Inc. SBM:1-2     " diet   1 -1  0  0  0  0  / divisor = 1 ;
   estimate "Inc.ABP Ln:6-3   " diet   0  0 -1  0  0  1  / divisor = 1 ;
   estimate "Inc.ABP Qr:36-5  " diet   0  0  1  0 -2  1  / divisor = 2 ; 
   estimate "Inc.ABP  34 vs 56" diet   0  0  1  1 -1  -1 / divisor = 2 ; 
run;