options nocenter ps=64 ls=80;
data a;
  infile 'berry.dat' firstobs = 2;
   input sample tissue $ conc1 conc2 conc3 conc4 conc5 conc6 conc7;
   wp = _N_;		/* identify whole plot */

/* univariate and split-plot type repeated measures */
/* note that proc glm forces sample*time even if you do not want it */
proc glm;
   class sample tissue;
   model conc1 conc2 conc3 conc4 conc5 conc6 conc7 = sample tissue / ss3;
   repeated julian 7 (179 200 221 242 269 290 320) polynomial;
   lsmeans tissue / out=lsm;
data plot; set lsm;		/* translate period to julian date */
   period = substr(_NAME_,5,1);
   julian = 168 + 21 * period;
   if period = 5 then julian = 269;
   if period = 6 then julian = 290;
   if period = 7 then julian = 320;
proc plot data=plot;
   plot lsmean*julian=tissue;

/* multivariate tests (but need to drop sample to analyze tissue over time */
proc glm data=a;
   class tissue;
   model conc1 conc2 conc3 conc4 conc5 conc6 conc7 = tissue / ss3 nouni;
   repeated julian 7 (179 200 221 242 269 290 320) polynomial / printe summary;
   lsmeans tissue;

data concs; set a;
   conc = conc1; date = 179; output;
   conc = conc2; date = 200; output;
   conc = conc3; date = 221; output;
   conc = conc4; date = 242; output;
   conc = conc5; date = 269; output;
   conc = conc6; date = 290; output;
   conc = conc7; date = 320; output;
   drop conc1--conc7;

proc mixed data=concs;		/* split plot using proc mixed */
   class tissue sample wp date;
   model conc = tissue date date*tissue;
   random sample tissue*sample;

proc mixed data=concs;		/* repeated measures using proc mixed */
   class tissue sample wp date;
   model conc = tissue date date*tissue;
   random sample;
   repeated / type=cs sub=tissue*sample;
   lsmeans date*tissue;

proc mixed data=concs;		/* polynomial contrasts in repeated measures */
   class tissue sample wp;
   model conc = tissue|date|date|date;
   random sample;
   repeated / type=cs sub=tissue*sample;

/* following not shown because it does not work properly
proc mixed data=concs;
   class tissue sample wp date;
   model conc = tissue date date*tissue;
   random sample;
   repeated / hlm type=un sub=tissue*sample;
   lsmeans date*tissue;
*/